SystemOrganization addCategory: #'Helvetia-Loader'!

Object subclass: #CHHelvetiaLoader
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Helvetia-Loader'!

!CHHelvetiaLoader class methodsFor: 'initialization' stamp: 'lr 4/2/2009 13:36'!
initialize
	self packages 
		do: [ :each |
			each size = 1
				ifTrue: [ self compilerClass evaluate: each first for: self logged: false ]
				ifFalse: [
					each first isSymbol
						ifFalse: [ self load: each first version: each second ]
						ifTrue: [
							(Preferences preferenceAt: each first)
								preferenceValue: each second ] ] ]
		displayingProgress: 'Loading Helvetia'! !

!CHHelvetiaLoader class methodsFor: 'public' stamp: 'lr 4/2/2009 16:22'!
load: anUrlString version: aString
	| repository group reader version |
	ProgressNotification signal: '' extra: aString.
	repository := MCHttpRepository
		location: anUrlString 
		user: '' password: ''.
	group := MCRepositoryGroup default.
	(group includes: repository)
		ifFalse: [ group addRepository: repository ]
		ifTrue: [ 
			repository := group repositories 
				detect: [ :each | each = repository] ].
	reader := repository versionReaderForFileNamed: aString , '.mcz'.
	reader isNil ifTrue: [ self error: 'Unable to load ' , aString printString ].
	version := reader version.
	version isNil ifTrue: [ self error: 'Unable to load ' , aString printString ].
	version load.
	version workingCopy repositoryGroup
		addRepository: repository! !

!CHHelvetiaLoader class methodsFor: 'initialization' stamp: 'lr 4/2/2009 16:30'!
packages
	^ #( " refactoring tools "	
		('http://www.squeaksource.com/AST' 'AST-lr.164')
		('http://www.squeaksource.com/RefactoringEngine' 'Refactoring-Core-lr.48')
		('http://www.squeaksource.com/RefactoringEngine' 'Refactoring-Spelling-lr.5')
		('http://source.lukas-renggli.ch/omnibrowser/' 'VB-Regex-sd.9')
		
		" smacc "
		('http://www.squeaksource.com/SmaccDevelopment' 'SmaCC-lr.13')
		('http://www.squeaksource.com/SmaccDevelopment' 'SmaCCDev-ms.19')
		
		" new compiler "
		('http://www.squeaksource.com/AST/' 'NewParser-marcus.denker.7')
		('http://www.squeaksource.com/NewCompiler/' 'NewCompiler-marcus.denker.290')
		(#compileBlocksAsClosures false)
		(#compileUseNewCompiler false)

		" omnibrowser "
		('http://source.lukas-renggli.ch/omnibrowser/' 'OmniBrowser-lr.442')
		('http://source.lukas-renggli.ch/omnibrowser/' 'OB-Standard-lr.407')
		('http://source.lukas-renggli.ch/omnibrowser/' 'OB-Morphic-lr.86')
		('http://source.lukas-renggli.ch/omnibrowser/' 'OB-Refactory-lr.150')
		('http://source.lukas-renggli.ch/omnibrowser/' 'OB-Regex-lr.18')
		('http://source.lukas-renggli.ch/omnibrowser/' 'OB-Tools-dkh.75')
		('http://source.lukas-renggli.ch/omnibrowser/' 'OB-SUnitIntegration-lr.13')
		('ToolSet default: StandardToolSet')
		
		" shout and ecompletion"
		('http://source.lukas-renggli.ch/unsorted/' 'RoelTyper-rw.60')
		('http://source.lukas-renggli.ch/unsorted/' 'Shout-lr.75')
		('http://source.lukas-renggli.ch/unsorted/' 'ECompletion-lr.95')
		('http://source.lukas-renggli.ch/unsorted/' 'ECompletionOmniBrowser-dc.4')
		
		" actual tools "
		('http://source.lukas-renggli.ch/petit' 'PetitParser-lr.70')
		('http://source.lukas-renggli.ch/helvetia' 'QuasiQuote-lr.40')
		('http://source.lukas-renggli.ch/helvetia' 'Helvetia-Core-lr.2')
		
		(#compileUseNewCompiler true)
		('http://source.lukas-renggli.ch/helvetia' 'Cutie-Helvetia-lr.1')
		('http://source.lukas-renggli.ch/helvetia' 'LanguageAspects-lr.61')
		('2 timesRepeat: [ LASmalltalkGrammar recompileAll ]')
		
		(#compileUseLanguageAspects true)
		('http://source.lukas-renggli.ch/helvetia' 'Cutie-LanguageAspects-lr.7'))! !
CHHelvetiaLoader initialize!